Guardar imágenes con BitmapData y PHP

import flash.display.BitmapData;

urlo = "";

//////////////////////////////////////////////////////////////////////////////////////////

//Esta es la función que se encarga de crear el objeto, "guardar los pixels" y mandarlos

function Capturar(mc:MovieClip) {

	//Muestro mi capa de progreso

	Progreso_mc._visible = true;

	Progreso_mc.Cerrar_bt._visible = false;

	//Creo el objeto bit map, del ancho y el alto del objeto que quiero guardar y dibujo este dentro

	mcBitmap = new BitmapData(mc._width, mc._height, true, 0xFFFFFF);

	mcBitmap.draw(mc);

	//Actualizo el estado de progreso

	Progreso_mc.Texto_txt.text = "Guardando imagen...";

	//Guardo en una matriz el valor de todos los pixels

	var cadena = new String();

	for (var i = 1; i<=mc._height; i++) {

		for (var j = 1; j<=mc._width; j++) {

			cadena += ","+mcBitmap.getPixel(j, i).toString(16);

		}

	}

	//Creo las variables para enviar y recibir del PHP

	enviarImagen = new LoadVars();

	respuesta = new LoadVars();

	//Al recibir los datos del PHP generador

	respuesta.onLoad = function(exito) {

		//Si todo ha ido bien

		if (exito) {

			//Actualizo el progreso y cargo en una nueva ventana la imagen generada

			Progreso_mc.Texto_txt.text = "Imagen recibida";

			Progreso_mc.Cerrar_bt._visible = true;

			getURL(urlo+unescape(this.archivo), "_blank");

			//Si algo ha fallado

		} else {

			//Mensaje de error

			Progreso_mc.Texto_txt.text = "Error al generar la imagen.";

			Progreso_mc.Cerrar_bt._visible = true;

		}

	};

	//Almaceno en la variable a enviar los valores de los pixels, y el ancho y alto de la imagen

	enviarImagen.imagen = cadena;

	enviarImagen.ancho = mc._width;

	enviarImagen.alto = mc._height;

	//Actualizo el progreso

	Progreso_mc.Texto_txt.text = "Generando jpg...";

	//Envio los datos de la imagen

	enviarImagen.sendAndLoad(urlo+"salvar.php",respuesta,"post");

}

//////////////////////////////////////////////////////////////////////////////////////////

//Código del botón guardar

Guardar_bt.onRelease = function() {

	//Al pulsar guardar, invoco a la funcion Capturar pasando como parametro el clip que quiero "guardar"

	Capturar(Escena_mc);

};

//////////////////////////////////////////////////////////////////////////////////////////

//Este es el código para hacer la "Pizarra". Muy sencilla, pero para el ejemplo vale.

Escena_mc.onMouseDown = function() {

	Escena_mc.Tiza_mc.lineStyle(3,"0x000000");

	Escena_mc.Tiza_mc.moveTo(_xmouse,_ymouse);

	Pintar = true;

};

Escena_mc.onMouseUp = function() {

	Pintar = false;

};

Escena_mc.onEnterFrame = function() {

	if (Pintar) {

		Escena_mc.Tiza_mc.lineTo(_xmouse,_ymouse);

	}

};

//////////////////////////////////////////////////////////////////////////////////////////

//////////////////////////////////////////////////////////////////////////////////////////

Progreso_mc._visible = false;

stop();