LocalConnection en Actionscript 3.0

Etiquetas: LocalConnection send connect

La clase Localconnection permite la comunicación entre varias peliculas SWF ejecutándose en el mismo cliente. El ejemplo que he utilizado es sencillo, por una parte tengo una pelicula con dos botones, play y stop, y por la otra una animación que reproduzco o paro según pulse los botones. El funcionamiento es el siguiente:

//////////////////////////////////////////////////////////////////////

//CÓDIGO DE LA PRIMERA PELÍCULA





//Importo las clases necesarias



import flash.net.LocalConnection;



//Creo la conexion



var conexion:LocalConnection = new LocalConnection();



//Le añado un listener para ver el estado



conexion.addEventListener(StatusEvent.STATUS, Estado);



//Función para ver el estado



function Estado(event:StatusEvent) {

        switch (event.level) {

                case "status" :

                trace("Envio correcto");

                break;

                case "error" :

                trace("Fallo al conectar");

                break;

        }

}



//Creo las funciones para los botones



function Reproducir(event:MouseEvent){

        var tiempo = new Date();

        conexion.send('esedeerre', 'Reproducir',tiempo.getTime());

        

}



function Parar(event:MouseEvent){

        var tiempo = new Date();

        conexion.send('esedeerre', 'Parar',tiempo.getTime());

}



//Añado los listener



Play_bt.addEventListener(MouseEvent.CLICK,Reproducir);

Stop_bt.addEventListener(MouseEvent.CLICK,Parar);







////////////////////////////////////////////////////////

//CÓDIGO PARA LA SEGUNDA PELÍCULA



////////////////////////////////////////////////////////

//Importo las clases necesarias



import flash.net.LocalConnection;



////////////////////////////////////////////////////////

//Creo la conexión, y me conecto con el nombre esedeerre



var conexion:LocalConnection = new LocalConnection();



conexion.client = this;



try{

        

        conexion.connect("esedeerre");

        

}catch (error:ArgumentError){

        

        trace("Error al conectar");

        

}



////////////////////////////////////////////////////////

//Creo las funciones para parar y reproducir el clip



function Reproducir(time){

        var tiempo = new Date();

        var espera = tiempo.getTime() - time;

        Texto_txt.text = "Se tardaron " + espera + " ms en recibir la última instrucción.";

        Coche_mc.play();

        

}



function Parar(time){

        var tiempo = new Date();

        var espera = tiempo.getTime() - time;

        Texto_txt.text = "Se tardaron " + espera + " ms en recibir la última instrucción.";

        Coche_mc.stop();

        

}



////////////////////////////////////////////////////////

//Dejo el coche parado al principio



Coche_mc.stop();

Texto_txt.text = "Esperando primera instrucción."

Además de las instrucciones para controlar la animación, paso como parámetro el momento en el que se hace la petición, para poder calcular el tiempo que tarda en ejecutarse. Estas serían las dos películas "en acción":