Cargar archivos de texto y XML con URLLoader

//Importo las clases necesarias

import flash.display.*;

import flash.events.*;

import flash.net.*;

//Asigno la url que se va a cargar

var url:String = "discos.xml";

//Carga el XML

function CargarXML() {

        //Creo el objeto cargador

        var loader:URLLoader = new URLLoader();

        //Le añado los listeners

        ponerListeners(loader);

        //Creo el objeto que contendrá la petición

        var peticion:URLRequest = new URLRequest(url);

        //Cargo la petición

        loader.load(peticion);

}

//Añade los listeners al cargador

function ponerListeners(dispatcher:IEventDispatcher):void {

        dispatcher.addEventListener(Event.COMPLETE, completeHandler);

        dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);

        dispatcher.addEventListener(Event.INIT, initHandler);

        dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);

        dispatcher.addEventListener(Event.OPEN, openHandler);

        dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);

}

//Funcion que se ejecuta cuando termina la descarga.

function completeHandler(event:Event):void {

        trace("completeHandler: " + event);

        trace(event.target.data);

}

//Se ejecuta al recibir un código de estado HTTP

function httpStatusHandler(event:HTTPStatusEvent):void {

        trace("httpStatusHandler: " + event);

}

//Se distribuye cuando las propiedades del objeto cargado están disponibles

//A partir de su distribucion podriamos modificar el objeto (ancho, escala, etc)

function initHandler(event:Event):void {

        trace("initHandler: " + event);

}

//Se ejecuta cuando hay un error de entrada/salida, por ejemplo, al intentar cargar un

//archivo inexistente

function ioErrorHandler(event:IOErrorEvent):void {

        trace("ioErrorHandler: " + event);

}

//Se ejecuta cuando comienza la operación de carga

function openHandler(event:Event):void {

        trace("openHandler: " + event);

}

//Se ejecuta periodicamente mientras dura la carga

function progressHandler(event:ProgressEvent):void {

        trace("progressHandler: bytesLoaded=" + event.bytesLoaded + " bytesTotal=" + event.bytesTotal);

}

//Empezamos

CargarXML();