Como hacer una pizarra en Actionscript 3.0

pizarra.graphics.lineStyle(10,0x000000);

pizarra.graphics.moveTo(100,100);

pizarra.graphics.lineTo(200,200);

pizarra.graphics.clear();

package{

	//Importo las clases necesarias

	import flash.display.Sprite;

	import flash.display.Shape;

	import flash.events.Event;

	import flash.events.MouseEvent;

	public class PizarraBasica extends Sprite{

		//Creo una variable de tipo Shape, que va a contener los dibujos

		public var pizarra:Shape;

		public function PizarraBasica():void{

			pizarra = new Shape();

			//Defino como vá a ser el tipo de lineas en "pizarra".

			//En este caso seria grosor 10, y color negro

			pizarra.graphics.lineStyle(10,0x000000);

			addChild(pizarra);

			//Añado los eventos al escenario

			stage.doubleClickEnabled = true;

			stage.addEventListener(MouseEvent.MOUSE_DOWN,siPintar);

			stage.addEventListener(MouseEvent.MOUSE_UP,noPintar);

			stage.addEventListener(MouseEvent.MOUSE_OUT,noPintar);

			stage.addEventListener(MouseEvent.DOUBLE_CLICK,borrar);

		}

		private function siPintar(e:Event):void{

			//Cuando el usuario presiona el botón izquierdo, el puntero debe empezar a pintar. 

			//El punto de inicio de ese nuevo trazo, debe ser el del puntero del ratón, por lo que 

			//muevo la posición del dibujo con moveTo

			pizarra.graphics.moveTo(mouseX,mouseY);

			//Añado un listener para que se pinten lineas siguiendo al puntero

			addEventListener(Event.ENTER_FRAME,pintar);

		}

		private function noPintar(e:Event):void{

			//Al soltar el ratón, elimino el evento para pintar lineas

			removeEventListener(Event.ENTER_FRAME,pintar);

		}

		private function pintar(e:Event):void{

			//La función lineTo pinta una linea hasta el punto (x,y)

			pizarra.graphics.lineTo(mouseX,mouseY);

		}

		private function borrar(e:Event):void{

			//La función clear borra lo que se haya dibujado en el objeto graphics, y restablece

			//la configuración de relleno y estilo de linea. 

			pizarra.graphics.clear();

			pizarra.graphics.lineStyle(10,0x000000);

		}

	}

}